プロテクトモードへの移行

文字出力の実装が終わりましたので、 32bitモードに移行することにしましょう。
32bitモードへの移行は次の流れで行います。

割り込みを禁止します(CLI命令)。
NMIを禁止します。
A20マスクを解除します。マスタブートローダの段階では、「A20マスク」、つまりメモリアドレスのビット20を強制的に 0 とする機能が有効になっています。つまり、address &= 0xffefffff; という演算が行われます。このままでは1Mを超えるメモリを有効に利用できませんので、 A20マスクの解除が必要になります。
LGDTによりGDTの位置をCPUに教えます。
CR0のbit 0に1を設定し、プロテクトモードに移行します。
far jmpによりCSに32bitセレクタを設定します。
DS、ES、FS、GS、SS、ESPに適切な値を設定します。
LIDTによりIDTの位置をCPUに教えます。
NMIを許可します。
割り込みを許可します(STI命令)。

前半は16bitモード、後半は32bitモードで実行されます。
CR0の値を設定しただけでは16bitモードのままです。
far jmpによりCSを更新することで32bitモードに切り替わります。

まず、NMIの禁止は次のようにします。

	mov	al, 0Dh
	out	70h, al
	in	al, 80h
	in	al, 71h

I/Oポート70hのbit 7に0を設定すればNMIは無効になります。
しかし、I/Oポート70hに書き込んだ場合、 I/Oポート71hからデータを読み込むことと決められています。
データを読み捨てているのはそのためです。
途中のI/Oポート80hはBIOSの診断コードの読み書きポートですが、データそのものには興味がありません。
ISAバスは1マイクロ秒のアクセス時間がかかるため、ウェイトポートとして使っています。

A20マスクの解除は次のようにします。

	mov	ax, 2401h
	stc
	int	15h
	jnc	boot_unmask_A20line_ok
	call	boot_kbc_wait
	mov	al, 0D1h
	out	64h, al
	call	boot_kbc_wait
	mov	al, 0DFh
	out	60h, al
	call	boot_kbc_wait
boot_unmask_A20line_ok:

INT 15h/AX=2401hはA20マスクを解除するBIOSコールです。
このコールで解除できない場合にはキーボードコントローラか I/O ポート 92h でマスクを解除する必要があります。
ここではキーボードコントローラを使って解除しています。
なお boot_kbc_wait は次のとおりです。

boot_kbc_wait:
	in	al, 64h
	test	al, 02h
	jnz	boot_kbc_wait
	ret

次に、GDTの位置をCPUに教え、32bitモードに切り替えます。
GDT用のdescriptorは次の8バイトの構造体です。

オフセット	サイズ	機能
+00h	2-byte	リミットのbit 15-0です。
+02h	2-byte	ベースアドレスのbit 15-0です。
+04h	1-byte	ベースアドレスのbit 23-16です。
+05h	1-byte	descriptorの種類とフラグです。 bit 7(80h)を設定すると、このdescriptorが存在することを示します。クリアするとアクセス時に例外が発生します。 bit 5-6(00h,20h,40h,60h)はdescriptorの特権レベル(DPL)を表します。 bit 4-0はdescriptorの種類を表します。特に、 bit 4(10h)はdescriptorがコードやデータのとき設定され、システム用のときクリアされます。 bit 4-0 の例を示します。 02h:LDT(別の構造体を使用)、 09h:32-bit TSS(別の構造体を使用)、 0Bh:32-bit TSS, busy (別の構造体を使用)、 0Eh:32-bit 割り込みゲート(別の構造体を使用)、 0Fh:32-bit トラップゲート(別の構造体を使用)、 10h:読み込み可能なデータ、 12h:読み込み・書き込み可能なデータ、 18h:実行可能コード、 1Ah:実行・読み込み可能なコード
+06h	1-byte	下位4bitはリミットのbit 19-16です。上位4bitはフラグです。 bit 7(80h)を設定すると、リミットが4096倍されます。 bit 6(40h)を設定すると、コードやスタックのデフォルトサイズが32bitになります。
+07h	1-byte	ベースアドレスのbit 31-24です。

まずはdescriptorの配列とそのポインタをメモリ上に準備します。
32bitで表現可能なアドレスすべてにアクセスできる descriptorにはいろいろな種類がありますが、セレクタのみを使うのであれば、 descriptorは以下の配列で十分です。
セレクタ08hがコード用、セレクタ10hがデータ用です。

	align	8,db 0
pm32_gdt_begin:
	; 00h: null selector.
	dw	0		; seg limit = 0Fh
	dw	0		; seg base 15:0 = 0
	dw	0		; seg base 23:16 = 0h, type = 0h
	db	0		; seglimit 19:16 and flags
	db	0		; segbase 31:24
	; 08h: 32-bit code selector. base=0, limit=4G.
	dw	0FFFFh		; seg limit = 0FFFFh
	dw	0000h		; seg base 15:0 = 0000h
	dw	9A00h		; seg base 23:16 = 00h, type = 9Ah(code)
	db	0CFh		; seglimit 19:16 and flags
	db	0h		; segbase 31:24
	; 10h: 32-bit data selector. base=0, limit=4G.
	dw	0FFFFh		; seg limit = 0FFFFh
	dw	0000h		; seg base 15:0 = 0000h
	dw	9200h		; seg base 23:16 = 00h, type = 92h(data)
	db	0CFh		; seglimit 19:16 and flags
	db	0h		; segbase 31:24
pm32_gdt_end:

CPUのマニュアルにはスタックにはexpand-downを使うといった記述がありますが、特にexpand-downを使う必要はありません。
GDTへのポインタは以下のとおりです。
リニアアドレスの計算に(0060h<<4)を使っているのはカーネルイメージが0060hに読み込まれているためです。テーブルが他の場所にある場合は適宜置き換えてください。

pm32_gdtr_top:
	dw	pm32_gdt_end - pm32_gdt_begin - 1	; limit (=length - 1)
	dd	(0060h << 4) + pm32_gdt_begin		; linear address

これらを用いて32bitに切り替えるコードを書くと、次のようになります。

	lgdt	[cs:pm32_gdtr_top]	; load GDTR.
	mov	eax, CR0
	or	al, 1
	mov	CR0, eax
	db	0EAh	; far jmp
	dw	(0060h<<4) + real_switch_to_pm32_entry	; entry point (offset)
	dw	0008h	; entry point (selector)
	BITS	32
real_switch_to_pm32_entry:
	mov	ax, 0010h
	mov	ds, ax
	mov	es, ax
	mov	ss, ax
	mov	esp, 110000h
	xor	eax, eax
	mov	fs, ax
	mov	gs, ax

CR0のbit 0に1を設定してプロテクトモードに移行した後、 csには0008hを、他のセレクタには0010hを設定し、また esp に暫定スタックとして 110000h を設定しています。
これにより、コード、データ、スタックを 32bitプロテクトモードに移行できました。
エントリポイントのオフセットが16bitの範囲に収まらない場合は、 db 0EAhの前にopsize prefix(db 66h)を入れて、オフセットを32bitで与えるとjmpできます。

[PR]衝撃！あなたの本当の裏の顔！:実は貴方はΟΔ県出身？ここで分かる真実