32bit割り込みハンドラの設定では、 割り込みハンドラのインストール方法を説明しました。
では、割り込みハンドラはどのように実装すれば良いのでしょうか？
これを実装するには、まず割り込み発生時にCPUが行う処理を 知る必要があります。

今回はDPLを0に設定した 32bitの割り込みゲートに限定して説明します。
割り込みが起きたときのCPUのモードにより、 呼び出されたときのスタックの内容は変わります。
CPUのモードは次の3種類です。

• カーネル内部(CPL=0)から呼び出される場合
• ユーザプロセス(CPL>0)から呼び出される場合
• 仮想86モード(EFLAGS.VM=1)から呼び出される場合

EFLAGS,CS,EIPをこの順で push します。 次に、割り込み・シングルステップ割り込みを禁止します。
最後に、descriptorから 割り込みハンドラを読み込み、 CS:EIPに設定します。
エラーコードのある例外の場合は、最後に エラーコードがpushされます。

ソフトウェア割り込みは#GP(0)を起こします。これはDPL=0としているためです。 #GP(0)を起こすとは、割り込みはエラーコードが0の例外0x0dとして 扱われることを意味します。
ユーザプロセスの場合、CPUはまず SS,ESPをこの順で push し、SS:ESPを TSSのSS0:ESP0の値で置き換えることで スタックをカーネルのスタックに切り替えます。
あとはカーネル内部(CPL=0)から呼び出される場合と同様の処理をします。

ソフトウェア割り込みは#GP(0)を起こします。 これはDPL=0としているためです。
はじめに GS,FS,DS,ES をこの順で push し、 4つのセグメントレジスタに null セレクタ(0)が設定されます。 これは、 DS/ES/FS/GSにリアルモード互換のセグメントが入っているためです。
あとはユーザプロセス(CPL>0)から呼び出される場合と同様の処理をします。

	; extern "C" void timer_handler(void);
timer_entry:
	cld
	push	ds
	push	es
	pushad
	mov	ax, 10h
	mov	ds, ax
	mov	es, ax
	call	_timer_handler
	popad
	pop	es
	pop	ds
	iret

gpfault_entry:
	cld
	push	ds
	push	es
	pushad
	mov	ax, 10h
	mov	ds, ax
	mov	es, ax
	push	esp
	call	_gpfault_handler
	add	esp, 4
	popad
	pop	es
	pop	ds
	add	esp, 4
	iret

struct GPFAULT_DATA
{
	unsigned	edi;
	unsigned	esi;
	unsigned	ebp;
	unsigned	dummy_esp;
	unsigned	ebx;
	unsigned	edx;
	unsigned	ecx;
	unsigned	eax;
	unsigned	saved_es;
	unsigned	saved_ds;
	unsigned	error_code;
	unsigned	eip;
	unsigned	cs;
	unsigned	eflags;
	unsigned	user_esp;
	unsigned	user_ss;
	unsigned	v86_es;
	unsigned	v86_ds;
	unsigned	v86_fs;
	unsigned	v86_gs;
};

extern "C" void gpfault_handler(GPFAULT_DATA *pdata)
{
	if (pdata->eflags & 0x20000) {
		// 仮想86用モードから呼ばれたときの処理
	} else if ((pdata->cs & 0x3) != 0) {
		// ユーザモードから呼ばれたときの処理
	} else {
		// カーネルから呼ばれたときの処理
	}
}

switch_to_v86:
	push	dword [V86_GS]
	push	dword [V86_FS]
	push	dword [V86_DS]
	push	dword [V86_ES]
	push	dword [V86_SS]
	push	dword [V86_ESP]
	mov	eax, [V86_EFLAGS]
	or	eax, 20000h	; VM bit
	push	eax
	push	dword [V86_CS]
	push	dword [V86_EIP]
	iret